Attachment #7 -Generate Graphics (rebuildmeta.csh)

#! /bin/csh
#
# This script will rebuild metafiles for 
# N-TRANS if problems occur
#
# Set variables for year, month, and date
#
set HOME = $NAWIPS/exe/scripts/localapps
cd ${HOME}
set YEAR = `date +%y`
set MONTH = `date +%m`
set MONTH1 = `date +%b`
set DAY = `date +%e`
set CYCLE = `cat cycle`
set MSOCYCLE = `cat msocycle`
set ETARES = `cat etares`
set AVNRES = `cat avnres`
set MSORES = `cat msores`
set MRFRES = `cat mrfres`
set NGMRES = `cat ngmres`
#
# Set variables for grib files
#
set etafile = (YxQAx YxQBx YxQCx YxQDx YxQEx YxQFx YxQGx YxQHx YxQIx)
set avnfile = (YxQBx YxQCx YxQDx YxQEx YxQFx YxQGx YxQHx YxQIx ZxQMx YxQJx ZxQNx YxQKx)
set msofile = (f00 f03 f06 f09 f12 f15 f18 f21 f24 f27 f30 f33)
set mrffile = (YxAAx YxACx YxAEx YxAGx YxAIx YxAJx YxAKx YxALx YxAMx YxAOx YxAQx YxASx YxAUx YxAWx YxAYx)
#
# Stop nag
#
$LDMHOME/ldm-5.0.2/bin/nag stop
#
# Based on responses...add files to new qf.q file
#
if ($ETARES == "Y" || $ETARES == "y") then   
          cd $NTRANS_META/eta
          rm eta*${DAY}_$CYCLE*
          cd $LDMHOME
                foreach file ($etafile)
          nag_add.pl us008_gf089_${YEAR}${MONTH}${DAY}${CYCLE}_${file}
          end
echo ''
echo 'The' $CYCLE'Z' $MONTH1 $DAY 'run of the ETA is being regenerated.'
endif
#
if ($AVNRES == "Y" || $AVNRES == "y") then
          cd $NTRANS_META/avn
          rm avn*${DAY}_$CYCLE*
          cd $LDMHOME
          nag_add.pl us008_gf081_${YEAR}${MONTH}${DAY}${CYCLE}_YxQAx 
          foreach file ($avnfile)
          nag_add.pl us008_gf077_${YEAR}${MONTH}${DAY}${CYCLE}_${file}
          end
echo ''
echo 'The' $CYCLE'Z' $MONTH1 $DAY 'run of the AVN is being regenerated.'
endif
#
if ($MSORES == "Y" || $MSORES == "y") then
          cd $NTRANS_META/mso
          rm mso*${DAY}_$MSOCYCLE*
          cd $LDMHOME
          foreach file ($msofile)
          nag_add.pl mso_${YEAR}${MONTH}${DAY}${MSOCYCLE}_${file}.gem
          end
echo ''
echo 'The' $MSOCYCLE'Z' $MONTH1 $DAY 'run of the MESOETA is being regenerated.'
endif
#
if ($MRFRES == "Y" || $MRFRES == "y") then
          cd $NTRANS_META/mrf
          rm mrf*${DAY}_$CYCLE*
          cd $LDMHOME
          foreach file ($mrffile)
          nag_add.pl us008_gf078_${YEAR}${MONTH}${DAY}${CYCLE}_${file}
          end
echo ''
echo 'The' $CYCLE'Z' $MONTH1 $DAY 'run of the MRF is being regenerated.'
endif
#
if ($NGMRES == "Y" || $NGMRES == "y") then       
          cd $NTRANS_META/ngm
          rm ngm*${DAY}_$CYCLE*
          cd $LDMHOME
          foreach file ($etafile)
          nag_add.pl us008_gf039_${YEAR}${MONTH}${DAY}${CYCLE}_${file}
          end        
echo ''
echo 'The' $CYCLE'Z' $MONTH1 $DAY 'run of the NGM is being regenerated.'
endif
#
# Restart NAG and exit from GEMPAK
#
$LDMHOME/ldm-5.0.2/bin/nag start
exit